【入門】射影変換(台形→長方形)(Scilab)【数値計算】

MATLAB、Python、Scilab、Julia比較ページはこちら
https://www.simulationroom999.com/blog/comparison-of-matlab-python-scilab/

はじめに
【再掲】変換元、変換先パラメータ
Scilabコード
処理結果
考察
まとめ

はじめに

の、

MATLAB,Python,Scilab,Julia比較第3章その107【射影変換(台形→長方形)⑤】

を書き直したもの。

射影変換の話の続き。
台形の画像を長方形にする。
今回はScilabでこれを実現する。

【再掲】変換元、変換先パラメータ

まずは、変換元、変換先パラメータを再掲。

\(
\begin{eqnarray}
(-0.5,-0.8)→&(-1,-1)\\
(-0.8,0.8)→&(-1,1)\\
(1,1)→&(1,1)\\
(0.4,-1)→&(1,-1)\\
\end{eqnarray}
\)

今回は、このパラメータによる射影変換をScilabで実現する。

Scilabコード

Scilabコードは以下になる。

homography.sci

function homography_img= homography(img, homography_matrix)
    // 画像サイズ取得
    [hight, width] = size(img);
    
    // 中心を0とした座標系を生成
    x_axis = linspace(-1, 1, width);
    y_axis = linspace(-1, 1, hight);
    [xim,yim] = meshgrid(x_axis, y_axis);
    
    // 座標x,y,1の3次元ベクトルの配列
    // n(:)表記で列ベクトル化したあとに転置して行ベクトル化
    points = [xim(:)';yim(:)'; ones(1, size(xim(:),1))];
    
    // 変換元座標算出(射影逆変換)
    points_affine = homography_matrix * points;
    
    // 画像と同一形状の2次元配列に変換元座標配列を生成
    dx = matrix(points_affine(1,:),[hight width]);
    dy = matrix(points_affine(2,:),[hight width]);
    ds = matrix(points_affine(3,:),[hight width]);
    dx = dx./ds;
    dy = dy./ds;
        
    // 変換元座標をピクセル位置に変換
    v = uint32(fix(min(max((dx+1)*width/2, 1), width ))); 
    h = uint32(fix(min(max((dy+1)*hight/2, 1), hight )));
    
    // 元画像と変換元座標を元に変換先へコピー
    homography_img = matrix(img(h+(v-1)*hight),[hight width]);
endfunction

homography_toRect_test.sci

function homography_toRect_test()
    //stacksize('max');
    img = imread('dog_homography_toTrapezoid.jpg');
    
    x0=-0.5; y0=-0.8;   // 左上
    x1=-0.8; y1= 0.8;   // 左下
    x2= 1; y2= 1;   // 右下
    x3= 0.4; y3=-1;   // 右上

    x0t=-1; y0t=-1;	// 左上変換先
    x1t=-1; y1t= 1;	// 左下変換先
    x2t= 1; y2t= 1;	// 右下変換先
    x3t= 1; y3t=-1;	// 右上変換先

    mat = [x0, y0, 1,  0,  0, 0, -x0*x0t, -y0*x0t;
            0,  0, 0, x0, y0, 1, -x0*y0t, -y0*y0t;
           x1, y1, 1,  0,  0, 0, -x1*x1t, -y1*x1t;
            0,  0, 0, x1, y1, 1, -x1*y1t, -y1*y1t;
           x2, y2, 1,  0,  0, 0, -x2*x2t, -y2*x2t;
            0,  0, 0, x2, y2, 1, -x2*y2t, -y2*y2t;
           x3, y3, 1,  0,  0, 0, -x3*x3t, -y3*x3t;
            0,  0, 0, x3, y3, 1, -x3*y3t, -y3*y3t];
    xfer = [x0t, y0t, x1t, y1t, x2t, y2t, x3t, y3t]';
    res = inv(mat)*xfer;

    homo_matrix = inv([ res(1) res(2) res(3);
                        res(4) res(5) res(6);
                        res(7) res(8), 1]);
                        
    homography_img = homography(img, homo_matrix);
    
    // グレースケール画像の書き込み
    imwrite(homography_img, 'dog_homography_toRectangle.jpg');    
endfunction

処理結果

処理結果は以下。

元画像

変換後画像

考察

変換はOK。
コードもMATLABと一緒。
コードの文法としてはかなり近いから、ほぼMATLABコードのままで動いてしまう。
そして、調整したパラメータ部分も一緒。

x0=-0.5; y0=-0.8;   // 左上
x1=-0.8; y1= 0.8;   // 左下
x2= 1; y2= 1;   // 右下
x3= 0.4; y3=-1;   // 右上

x0t=-1; y0t=-1;	// 左上変換先
x1t=-1; y1t= 1;	// 左下変換先
x2t= 1; y2t= 1;	// 右下変換先
x3t= 1; y3t=-1;	// 右上変換先