【入門】アフィン逆変換時の行列合成(Scilab)【数値計算】

MATLAB、Python、Scilab、Julia比較ページはこちら
https://www.simulationroom999.com/blog/comparison-of-matlab-python-scilab/

はじめに
【再掲】プログラムで実現したいアフィン行列の合成
Scilabコード
処理結果
考察
まとめ

はじめに

の、

MATLAB,Python,Scilab,Julia比較第3章その85【アフィン行列の合成⑨】

を書き直したもの。

アフィン変換のアフィン行列の合成の話。
今回はScilabで実施する。

【再掲】プログラムで実現したいアフィン行列の合成

まずは、実現したいアフィン行列の合成。

\(
\begin{eqnarray}
\begin{bmatrix}
x\prime\\
y\prime\\
1
\end{bmatrix}=
\begin{bmatrix}
1 & m_x & 0 \\
m_y & 1 & 0 \\
0 & 0 & 1
\end{bmatrix}
\begin{bmatrix}
\cos(30^\circ) & -\sin(30^\circ) & 0 \\
\sin(30^\circ) & \cos(30^\circ) & 0 \\
0 & 0 & 1
\end{bmatrix} \\
\begin{bmatrix}
1 & 0 & T_x \\
0 & 1 & T_y \\
0 & 0 & 1
\end{bmatrix}
\begin{bmatrix}
S_x & 0 & 0 \\
0 & S_y & 0 \\
0 & 0 & 1
\end{bmatrix}
\begin{bmatrix}
x\\
y\\
1
\end{bmatrix}
\end{eqnarray}
\)

そして、アフィン逆変換のアルゴリズム都合で実際に使用する数式がこれ。

\(
\begin{eqnarray}
\begin{bmatrix}
x\\
y\\
1
\end{bmatrix}=
\begin{bmatrix}
S_x & 0 & 0 \\
0 & S_y & 0 \\
0 & 0 & 1
\end{bmatrix}^{-1}
\begin{bmatrix}
1 & 0 & T_x \\
0 & 1 & T_y \\
0 & 0 & 1
\end{bmatrix}^{-1}
\begin{bmatrix}
\cos(30^\circ) & -\sin(30^\circ) & 0 \\
\sin(30^\circ) & \cos(30^\circ) & 0 \\
0 & 0 & 1
\end{bmatrix}^{-1}\\
\begin{bmatrix}
1 & m_x & 0 \\
m_y & 1 & 0 \\
0 & 0 & 1
\end{bmatrix}^{-1}
\begin{bmatrix}
x\prime\\
y\prime\\
1
\end{bmatrix}
\end{eqnarray}
\)

これをScilabで実現する。

Scilabコード

Scilabコードは以下になる。

canvas_expansion.sci

function img = canvas_expansion(img, x, y)
    [H, W] = size(img);
    WID = W+x;
    HID = H+y;
    e_img = uint8(zeros(HID, WID));
    e_img(int32((HID-H)/2)+1:int32((HID+H)/2), int32((WID-W)/2)+1:int32((WID+W)/2)) = img;
    img = e_img;
endfunction

affine_transformation.sci

function affine_img= affine_transformation(img, affine_matrix)
    // 画像サイズ取得
    [hight, width] = size(img);
    
    // 中心を0とした座標系を生成
    x_axis = linspace(-1, 1, width);
    y_axis = linspace(-1, 1, hight);
    [xim,yim] = meshgrid(x_axis, y_axis);
    
    // 座標x,y,1の3次元ベクトルの配列
    // n(:)表記で列ベクトル化したあとに転置して行ベクトル化
    points = [xim(:)';yim(:)'; ones(1, size(xim(:),1))];
    
    // 変換元座標算出(アフィン逆変換)
    points_affine = affine_matrix * points;
    
	// 画像と同一形状の2次元配列に変換元座標配列を生成
	dx = matrix(points_affine(1,:),[hight width]);
	dy = matrix(points_affine(2,:),[hight width]);
    
    // 変換元座標をピクセル位置に変換
    v = uint32(fix(min(max((dx+1)*width/2, 1), width ))); 
    h = uint32(fix(min(max((dy+1)*hight/2, 1), hight )));
    
    // 元画像と変換元座標を元に変換先へコピー
    affine_img = matrix(img(h+(v-1)*hight),[hight width]);
endfunction

affine_test.sci

function affine_test()
    //stacksize('max');
    
    img = imread('dog.jpg');
    r = img(:,:,1);
    g = img(:,:,2);
    b = img(:,:,3);
    
    // SDTVグレースケール
    img = uint8([0.2990 * double(r) ...
                + 0.5870 * double(g) + 0.1140 * double(b) ]);
    
    img = canvas_expansion(img, 800, 800);
    
    sx = 1;
    sy = -1;
    tx = 0.5;
    ty = 0;
    theta = 150/180*%pi;
    mx = tan(0/180*%pi);
    my = tan(0/180*%pi);
    
    scaling_matrix     = [ 1/sx       0  0;
                              0    1/sy  0;
                              0       0  1];

    translation_matrix = [ 1 0 -tx;
                           0 1 -ty;
                           0 0 1];
    rotation_matrix    = [ cos(theta) -sin(theta)  0;
                           sin(theta)  cos(theta)  0;
                                   0           0   1];
    
    shear_matrix       = [  1 mx  0;
                          -my  1  0;
                            0  0  1];
    
	affine_matrix = scaling_matrix*translation_matrix*rotation_matrix*shear_matrix;
    
    affine_img = affine_transformation(img, affine_matrix);
    
    // グレースケール画像の書き込み
    imwrite(affine_img, 'dog_affine.jpg');    
endfunction