MATLAB,Python,Scilab,Julia比較第3章その115【射影変換、アフィン変換合成⑦】

バックナンバーはこちら。
https://www.simulationroom999.com/blog/compare-matlabpythonscilabjulia3-backnumber/

はじめに
登場人物
【再掲】数式とパラメータ
Scilabコード
処理結果
考察
まとめ

はじめに

射影変換とアフィン変換の合成をプログラムで実現する。
今回はScilab。

登場人物

博識フクロウのフクさん

イラストACにて公開の「kino_k」さんのイラストを使用しています。
https://www.ac-illust.com/main/profile.php?id=iKciwKA9&area=1

エンジニア歴8年の太郎くん

イラストACにて公開の「しのみ」さんのイラストを使用しています。
https://www.ac-illust.com/main/profile.php?id=uCKphAW2&area=1

【再掲】数式とパラメータ

太郎くん

まずは、数式とパラメータを再掲。

射影(逆)変換

\(
\begin{eqnarray}
\begin{bmatrix}
x\prime\\
y\prime\\
1
\end{bmatrix}&=&
\begin{bmatrix}
a&b&c\\
d&e&f\\
g&h&1
\end{bmatrix}^{-1}
\begin{bmatrix}
S_x&0&0\\
0&S_y&0\\
0&0&1
\end{bmatrix}^{-1}\\
&&\begin{bmatrix}
1&0&T_x\\
0&1&T_y\\
0&0&1
\end{bmatrix}^{-1}
\begin{bmatrix}
\cos(\theta)&-\sin(\theta)&0\\
\sin(\theta)&\cos(\theta)&0\\
0&0&1
\end{bmatrix}^{-1}
\begin{bmatrix}
x\\
y\\
1
\end{bmatrix}
\end{eqnarray}
\)

パラメータ

射影変換

\(
\begin{eqnarray}
(-1,-1)→&(-0.5,-0.8)\\
(-1,1)→&(-0.8,0.8)\\
(1,1)→&(1,1)\\
(1,-1)→&(0.4,-1)\\
\end{eqnarray}
\)

伸縮アフィン
　縦横を1/2へ縮小

移動アフィン
　x軸方向+0.5

回転アフィン
　+60°

フクさん

これをScilabで実現する。

Scilabコード

フクさん

Scilabコードは以下。

canvas_expansion.sci

function img = canvas_expansion(img, x, y)
    [H, W] = size(img);
    WID = W+x;
    HID = H+y;
    e_img = uint8(zeros(HID, WID));
    e_img(int32((HID-H)/2)+1:int32((HID+H)/2), int32((WID-W)/2)+1:int32((WID+W)/2)) = img;
    img = e_img;
endfunction

homography.sci

function homography_img= homography(img, homography_matrix)
    // 画像サイズ取得
    [hight, width] = size(img);
    
    // 中心を0とした座標系を生成
    x_axis = linspace(-1, 1, width);
    y_axis = linspace(-1, 1, hight);
    [xim,yim] = meshgrid(x_axis, y_axis);
    
    // 座標x,y,1の3次元ベクトルの配列
    // n(:)表記で列ベクトル化したあとに転置して行ベクトル化
    points = [xim(:)';yim(:)'; ones(1, size(xim(:),1))];
    
    // 変換元座標算出(射影逆変換)
    points_affine = homography_matrix * points;
    
    // 画像と同一形状の2次元配列に変換元座標配列を生成
    dx = matrix(points_affine(1,:),[hight width]);
    dy = matrix(points_affine(2,:),[hight width]);
    ds = matrix(points_affine(3,:),[hight width]);
    dx = dx./ds;
    dy = dy./ds;
        
    // 変換元座標をピクセル位置に変換
    v = uint32(fix(min(max((dx+1)*width/2, 1), width ))); 
    h = uint32(fix(min(max((dy+1)*hight/2, 1), hight )));
    
    // 元画像と変換元座標を元に変換先へコピー
    homography_img = matrix(img(h+(v-1)*hight),[hight width]);
endfunction

homography_affine.sci

function homography_affine()
    //stacksize('max');
    img = imread('dog.jpg');
    r = img(:,:,1);
    g = img(:,:,2);
    b = img(:,:,3);
    
    // SDTVグレースケール
    img = uint8([0.2990 * double(r) ...
                + 0.5870 * double(g) + 0.1140 * double(b) ]);
    
    img = canvas_expansion(img, 100, 100);
    
    sx = 0.5;
    sy = 0.5;
    tx = 0.5;
    ty = 0;
    theta = 60/180*%pi;
    
    x0=-1; y0=-1;   // 左上
    x1=-1; y1= 1;   // 左下
    x2= 1; y2= 1;   // 右下
    x3= 1; y3=-1;   // 右上

    x0t=-0.5; y0t=-0.8;	// 左上変換先
    x1t=-0.8; y1t= 0.8;	// 左下変換先
    x2t= 1; y2t= 1;	// 右下変換先
    x3t= 0.4; y3t=-1;	// 右上変換先

    mat = [x0, y0, 1,  0,  0, 0, -x0*x0t, -y0*x0t;
            0,  0, 0, x0, y0, 1, -x0*y0t, -y0*y0t;
           x1, y1, 1,  0,  0, 0, -x1*x1t, -y1*x1t;
            0,  0, 0, x1, y1, 1, -x1*y1t, -y1*y1t;
           x2, y2, 1,  0,  0, 0, -x2*x2t, -y2*x2t;
            0,  0, 0, x2, y2, 1, -x2*y2t, -y2*y2t;
           x3, y3, 1,  0,  0, 0, -x3*x3t, -y3*x3t;
            0,  0, 0, x3, y3, 1, -x3*y3t, -y3*y3t];
    xfer = [x0t, y0t, x1t, y1t, x2t, y2t, x3t, y3t]';
    res = inv(mat)*xfer;

    homo_matrix = inv([ res(1) res(2) res(3);
                        res(4) res(5) res(6);
                        res(7) res(8), 1]);
                        
    scaling_matrix     = [ 1/sx       0  0;
                              0    1/sy  0;
                              0       0  1];

    translation_matrix = [ 1 0 -tx;
                           0 1 -ty;
                           0 0 1];
    rotation_matrix    = [ cos(theta) -sin(theta)  0;
                           sin(theta)  cos(theta)  0;
                                   0           0   1];
    
	homography_matrix = homo_matrix*scaling_matrix ...
                            *translation_matrix*rotation_matrix;
    
    affine_img = homography(img, homography_matrix);
    
    // グレースケール画像の書き込み
    imwrite(affine_img/255, 'dog_homography_affine.jpg');    
endfunction