【入門】アフィン変換(Scilab)【数値計算】

MATLAB、Python、Scilab、Julia比較ページはこちら
https://www.simulationroom999.com/blog/comparison-of-matlab-python-scilab/

はじめに
アフィン変換のプログラミングに向けて【再掲】
Scilabコード
処理結果
考察
まとめ

はじめに

の、

MATLAB,Python,Scilab,Julia比較第3章その75【アフィン変換⑲】

を書き直したもの。

アフィン変換のプログラミング。
今回は、Scilabで実施。

アフィン変換のプログラミングに向けて【再掲】

まずは処理手順の再掲。

画像サイズの取得
中心を0とした座標系の生成
- X軸、Y軸ともに-1～1の範囲の座標系として扱う
座標\(x\prime,y\prime,1\)の3次元ベクトル配列の生成。
- ※ 全座標に対して一括でアフィン逆変換を実施するため。
変換元座標の算出(アフィン逆変換)
画像と同一形状の2次元配列に変換元座標配列を生成。
変換元の座標系-1～1をピクセル位置に変換。
元画像と変換元座標を元に変換先へコピー。

これをScilabで実施する。

Scilabコード

Scilabコードは以下になる。

affine_transformation.sci

function affine_img= affine_transformation(img, affine_matrix)
    // 画像サイズ取得
    [hight, width] = size(img);
    
    // 中心を0とした座標系を生成
    x_axis = linspace(-1, 1, width);
    y_axis = linspace(-1, 1, hight);
    [xim,yim] = meshgrid(x_axis, y_axis);
    
    // 座標x,y,1の3次元ベクトルの配列
    // n(:)表記で列ベクトル化したあとに転置して行ベクトル化
    points = [xim(:)';yim(:)'; ones(1, size(xim(:),1))];
    
    // 変換元座標算出(アフィン逆変換)
    points_affine = affine_matrix * points;
    
	// 画像と同一形状の2次元配列に変換元座標配列を生成
	dx = matrix(points_affine(1,:),[hight width]);
	dy = matrix(points_affine(2,:),[hight width]);
    
    // 変換元座標をピクセル位置に変換
    v = uint32(fix(min(max((dx+1)*width/2, 1), width ))); 
    h = uint32(fix(min(max((dy+1)*hight/2, 1), hight )));
    
    // 元画像と変換元座標を元に変換先へコピー
    affine_img = matrix(img(h+(v-1)*hight),[hight width]);
endfunction

canvas_expansion.sci

function img = canvas_expansion(img, x, y)
    [H, W] = size(img);
    WID = W+x;
    HID = H+y;
    e_img = uint8(zeros(HID, WID));
    e_img(int32((HID-H)/2)+1:int32((HID+H)/2), int32((WID-W)/2)+1:int32((WID+W)/2)) = img;
    img = e_img;
endfunction

affine_scale_test.sci

function affine_scale_test()
    img = imread('dog.jpg');
    r = img(:,:,1);
    g = img(:,:,2);
    b = img(:,:,3);
    
    // SDTVグレースケール
    img = uint8([0.2990 * double(r) ...
                + 0.5870 * double(g) + 0.1140 * double(b) ]);
    
    img = canvas_expansion(img, 300, 300);
    
    sx = -1;
    sy = 1.5;
    
    affine_matrix     = inv([ sx     0  0;
                               0    sy  0;
                               0     0  1]);
    
    affine_img = affine_transformation(img, affine_matrix);
    
    // グレースケール画像の書き込み
    imwrite(affine_img, 'dog_affine_scaling.jpg');    
endfunction