【入門】射影変換(Scilab)【数値計算】

MATLAB、Python、Scilab、Julia比較ページはこちら
https://www.simulationroom999.com/blog/comparison-of-matlab-python-scilab/

はじめに
【再掲】射影変換の処理の流れ
Scilabコード
処理結果
考察
まとめ

はじめに

の、

MATLAB,Python,Scilab,Julia比較第3章その101【射影変換⑮】

を書き直したもの。

アフィン変換の拡張と言われている射影変換の話。
実際にプログラムを組んでみる。
今回はScilabで実施。

【再掲】射影変換の処理の流れ

まずは処理の流れを再掲。

画像の読み込み
変換元座標の確定
変換先座標の確定
\(a～h\)の算出
射影変換行列の確定
射影変換
画像保存

これをScilabで実現する。

Scilabコード

Scilabコードは以下になる。

canvas_expansion.sci

function img = canvas_expansion(img, x, y)
    [H, W] = size(img);
    WID = W+x;
    HID = H+y;
    e_img = uint8(zeros(HID, WID));
    e_img(int32((HID-H)/2)+1:int32((HID+H)/2), int32((WID-W)/2)+1:int32((WID+W)/2)) = img;
    img = e_img;
endfunction

homography.sci

function homography_img= homography(img, homography_matrix)
    // 画像サイズ取得
    [hight, width] = size(img);
    
    // 中心を0とした座標系を生成
    x_axis = linspace(-1, 1, width);
    y_axis = linspace(-1, 1, hight);
    [xim,yim] = meshgrid(x_axis, y_axis);
    
    // 座標x,y,1の3次元ベクトルの配列
    // n(:)表記で列ベクトル化したあとに転置して行ベクトル化
    points = [xim(:)';yim(:)'; ones(1, size(xim(:),1))];
    
    // 変換元座標算出(射影逆変換)
    points_affine = homography_matrix * points;
    
    // 画像と同一形状の2次元配列に変換元座標配列を生成
    dx = matrix(points_affine(1,:),[hight width]);
    dy = matrix(points_affine(2,:),[hight width]);
    ds = matrix(points_affine(3,:),[hight width]);
    dx = dx./ds;
    dy = dy./ds;
        
    // 変換元座標をピクセル位置に変換
    v = uint32(fix(min(max((dx+1)*width/2, 1), width ))); 
    h = uint32(fix(min(max((dy+1)*hight/2, 1), hight )));
    
    // 元画像と変換元座標を元に変換先へコピー
    homography_img = matrix(img(h+(v-1)*hight),[hight width]);
endfunction

homography_toTrape_test.sci

function homography_toTrape_test()
    //stacksize('max');
    img = imread('dog.jpg');
    r = img(:,:,1);
    g = img(:,:,2);
    b = img(:,:,3);
    
    // SDTVグレースケール
    img = uint8([0.2990 * double(r) ...
                + 0.5870 * double(g) + 0.1140 * double(b) ]);
    
    img = canvas_expansion(img, 100, 100);
    
    x0=-1; y0=-1;   // 左上
    x1=-1; y1= 1;   // 左下
    x2= 1; y2= 1;   // 右下
    x3= 1; y3=-1;   // 右上

    x0t=-0.5; y0t=-0.8;	// 左上変換先
    x1t=-0.8; y1t= 0.8;	// 左下変換先
    x2t= 1; y2t= 1;	// 右下変換先
    x3t= 0.4; y3t=-1;	// 右上変換先

    mat = [x0, y0, 1,  0,  0, 0, -x0*x0t, -y0*x0t;
            0,  0, 0, x0, y0, 1, -x0*y0t, -y0*y0t;
           x1, y1, 1,  0,  0, 0, -x1*x1t, -y1*x1t;
            0,  0, 0, x1, y1, 1, -x1*y1t, -y1*y1t;
           x2, y2, 1,  0,  0, 0, -x2*x2t, -y2*x2t;
            0,  0, 0, x2, y2, 1, -x2*y2t, -y2*y2t;
           x3, y3, 1,  0,  0, 0, -x3*x3t, -y3*x3t;
            0,  0, 0, x3, y3, 1, -x3*y3t, -y3*y3t];
    xfer = [x0t, y0t, x1t, y1t, x2t, y2t, x3t, y3t]';
    res = inv(mat)*xfer;

    homo_matrix = inv([ res(1) res(2) res(3);
                        res(4) res(5) res(6);
                        res(7) res(8), 1]);
                        
    homography_img = homography(img, homo_matrix);
    
    // グレースケール画像の書き込み
    imwrite(homography_img/255, 'dog_homography_toTrapezoid.jpg');    
endfunction

処理結果

処理結果は以下。

考察

これも動作はOK。
そして、射影変換の\(s\)についての解決は以下のコードになる。

ds = matrix(points_affine(3,:),[hight width]);
dx = dx./ds;
dy = dy./ds;

これもアフィン変換の使い回しでほぼOKな状態となる。

まとめ

Scilabで射影変換実施。
基本的にはMATLABと一緒で、射影変換のsを解決するコードを追加すればOK。

MATLAB、Python、Scilab、Julia比較ページはこちら