【入門】ガウシアンフィルタ(Scilab)【数値計算】

MATLAB、Python、Scilab、Julia比較ページはこちら
https://www.simulationroom999.com/blog/comparison-of-matlab-python-scilab/

はじめに
使用する畳み込みカーネルと画像
Scilabコード
処理結果
考察
まとめ

はじめに

の、
MATLAB,Python,Scilab,Julia比較第3章その23【ガウシアンフィルタ⑨】

を書き直したもの。

畳み込み演算のガウシアンフィルタの話になる。
今回はScilabで実施してみる。

使用する畳み込みカーネルと画像

まずは畳み込みカーネルと画像の再掲。

畳み込みカーネル

\(
\displaystyle K_{3\times3}=\frac{1}{16}
\begin{bmatrix}
1 & 2 & 1 \\
2 & 4 & 2 \\
1 & 2 & 1 \\
\end{bmatrix}
\)

画像

これをScilabで実現する。

Scilabコード

Scilabコードは以下になる。

convolution2d.sci

function out = convolution2d(img, Kernel)
    [m, n] = size(Kernel);  // カーネルサイズ取得
    
    // カーネル中心からみた幅
    dy = int32((m-1)/2);  // カーネル上下幅
    dx = int32((n-1)/2);  // カーネル左右幅
    
    [h, w] = size(img);        // イメージサイズ
    out = zeros(h, w);         // 出力用イメージ
    
    // 畳み込み
    for y = dy+1:(h - dy)
        for x = dx+1:(w-dx)
            out(y, x) = sum( double(img(y-dy:y+dy, x-dx:x+dx)).*Kernel );
        end
    end
endfunction

gaussian_test.sci

function [] = gaussian_test()
    img = imread('dog.jpg');
    
    [h, w, c] = size(img);
    
    // ガウシアンフィルタ用のkernel
    kernel_gauss = [ 1/16  2/16  1/16; 
                     2/16  4/16  2/16; 
                     1/16  2/16  1/16];
    img_gauss = uint8(zeros(h, w, c));
    
    // ガウシアンフィルタ
    img_gauss(:,:,1) = convolution2d(img(:,:,1), kernel_gauss);
    img_gauss(:,:,2) = convolution2d(img(:,:,2), kernel_gauss);
    img_gauss(:,:,3) = convolution2d(img(:,:,3), kernel_gauss);
    
    imwrite(img_gauss,'dog_gaussian.jpg');
endfunction

処理結果

処理結果は以下。

考察

もうMATLABと一緒と言っても良いレベル。
実際、ほぼコピペで済ましている。

ただし、よく見ると、
out(y, x) = sum( double(img(y-dy:y+dy, x-dx:x+dx)).*Kernel );
部分のsumが一個で済んでいる。
sumに関しては、MATLABと挙動が異なり、行列全体の総和になる。
行、列に対しての総和を取りたい場合は、第2引数に1を入れれば列の総和、2を入れれば行の総和になる。

相変わらず似てるのに、細かい部分で差異が出る。
こういうのを経験して、ツール、言語の特性を把握していくしかない。